Forumul organizatiei Pontes - www.pontes.ro

Cod: Selectaţi tot

void main()
{
// cream o fereastra valabila pe durata procesului:
show_game_window("Inversare fişiere");

// intrebam extensia fisierelor de gasit care va fi scrisa fara punct in fata:
string extension=input_box("Extensia", "Scrieţi extensia fişierelor de inversat fără punct:");

// o variabila care va tine continutul unui fisier pana acesta va fi pus in fisierul nou:
string temp="";

// pentru a denumi cu un numar de zerouri in fata astfel incat sa fie o ordonare alfabetica, cream o variabila care va fi ajustata in functie de numarul fisierului::
string prefix="";

// umplem un array cu toate fisierele gasite in folderul curent cu extensia scrisa:
string[] all_files=find_files("*."+extension);

// verificari daca e scrisa vreo extensie sau a fost gasit vreun fisier:
// daca nu s-a scris nimic la extensie:
if(extension=="")
{
alert("Eroare!", "Nu a fost scrisă o extensie.");
exit();
}

// daca nu e gasit nici un fisier:
if(all_files.length==0)
{
alert("Eroare!", "Nu au fost gasite fişiere cu extensia "+extension+".");
exit();
}

// intrebam numele directorului in care vor fi rearanjate fisierele:
string directory_name=input_box("Creare folder", "Scrieţi numele directorului în care să fie salvate fişierele în ordine inversă:");

// daca nu e scris nimic la folder, il denumim inversate:
if(directory_name=="") directory_name="Inversate";

// cream directorul:
directory_create(directory_name);

// cream un cronometru pentru a vedea cat a durat rearanjarea:
timer t;

// un for care va lua fiecare fisier in parte dupa un algoritm si il va muta in folderul creat cu numarul corespunzator:
for(int i=all_files.length()-1; i>=0; i--)
{
file f;
f.open(all_files[i], "rb");
temp=f.read(0);
f.close();

wait(5);

int j=all_files.length()-i;

// calcularea prefixului:
if(j<10) prefix="000";
else if(j>=10&&j<100) prefix="00";
else if(j>=100&&j<1000) prefix="0";
else prefix="";
// sfarsit calculare prefix.

file g;
g.open(directory_name+"//"+prefix+j+"."+extension, "wb");
g.write(temp);
g.close();
} // end for.

// un alert care anunta:
alert("Succes!", "Procesul a durat "+t.elapsed+" milisecunde.");
exit();
}

Cod: Selectaţi tot

#Include <File.au3>
#Include <Array.au3>
; Alegem folder-ul din casuta de dialog
$dir=FileSelectFolder("Alege directorul cu fisiere","")
; Alegem extensia (aici implicit e gif)
$ext=InputBox("Scrieti extensia","Scrieti extensia fara punct a fisierelor ce doriti sa fie procesate!", "gif")
; Incarcam fisierele intr-un sir
$data=_FileListToArray($dir,"*"&$ext)
; Aflam numarul de fisiere si il stocam intr-o variabila
$nrFisiere=_ArrayDelete($data,0)
; stocam sirul original de fisiere
$originale=$data
; inversam sirul de fisiere
_ArrayReverse($data)
; cream un director temporar in directorul actual
DirCreate($dir&"\temp")
; redenumim fiecare fisier in directorul temporar cu numele celui din sirul inversat
for $x=0 to $nrFisiere-1
	FileMove($dir&"\"&$originale[$x],$dir&"\temp\"&$data[$x])
Next
; redenumim fiecare fisier din directorul temporar inapoi in directorul actual
for $x=0 to $nrFisiere-1
	FileMove($dir&"\temp\"&$data[$x],$dir&"\"&$data[$x])
Next
; stergem directorul temporar
DirRemove($dir&"\temp")
; afisam un mesaj pentru a confirma terminarea scriptului
MsgBox(64,"Succes!","Au fost redenumite "&$nrFisiere&" fisiere"&@CRLF&"La revedere!")
Exit